HTML::LinkExtor

LIB::HTML::LINKEXTOR(1User Contributed Perl DocumentatiLIB::HTML::LINKEXTOR(1)



NAME
       HTML::LinkExtor - Extract links from an HTML document

SYNPOSIS
        require HTML::LinkExtor;
        $p = HTML::LinkExtor->new(\&cb, "http://www.sn.no/");
        sub cb {
            my($tag, %links);
            print "$tag @{[%links]}\n";
        }
        $p->parse_file("index.html");


DESCRIPTION
       The HTML::LinkExtor (link extractor) is an HTML parser that takes a
       callback routine as parameter.  This routine is then called as the
       various link attributes are recognized.

       The HTML::LinkExtor is a subclass of HTML::Parser. This means that the
       document should be given to the parser by calling the $p->parse() or
       $p->parse_file() methods.

       $p = HTML::LinkExtor->new([$callback[, $base]])

       The constructor takes two optional argument. The first is a reference
       to a callback routine. It will be called as links are found. If a
       callback is not provided, then links are just accumulated internally
       and can be retrieved by calling the $p->links() method. The $base is an
       optional base URL used to absolutize all URLs found.

       The callback is called with the lowercase tag name as first argument,
       and then all link attributes as separate key/value pairs.  All non-link
       attributes are removed.

       @links = $p->links

       Return links found in the document as an array.  Each array element
       contains an anonymous array with the follwing values:

         [$tag, $attr => $url1, $attr2 => $url2,...]

       Note that $p->links will always be empty if a callback routine was
       provided when the the HTML::LinkExtor manpage was created.

EXAMPLE
       This is an example showing how you can extract links as a document is
       received using LWP:

         use LWP::UserAgent;
         use HTML::LinkExtor;
         use URI::URL;

         $url = "http://www.sn.no/";  # for instance
         $ua = new LWP::UserAgent;

         # Set up a callback that collect image links
         my @imgs = ();
         sub callback {
            my($tag, %attr) = @_;
            return if $tag ne 'img';  # we only look closer at <img ...>
            push(@imgs, values %attr);
         }

         # Make the parser.  Unfortunately, we don't know the base yet (it might
         # be diffent from $url)
         $p = HTML::LinkExtor->new(\&callback);

         # Request document and parse it as it arrives
         $res = $ua->request(HTTP::Request->new(GET => $url), sub {$p->parse($_[0])});

         # Expand all image URLs to absolute ones
         my $base = $res->base;
         @imgs = map { $_ = url($_, $base)->abs; } @imgs;

         # Print them out
         print join("\n", @imgs), "\n";


SEE ALSO
       the HTML::Parser manpage

AUTHOR
       Gisle Aas <aas@sn.no>




3rd Berkeley Distribution    perl 5.003, patch 07      LIB::HTML::LINKEXTOR(1)